Main Page

Première requête

PREFIX tdml: <https://tredemulor.wikibase.cloud/entity/>
PREFIX tdmlt: <https://tredemulor.wikibase.cloud/prop/direct/>
PREFIX tdmlp: <https://tredemulor.wikibase.cloud/prop/>
PREFIX tdmlps: <https://tredemulor.wikibase.cloud/prop/statement/>
PREFIX tdmlpq: <https://tredemulor.wikibase.cloud/prop/qualifier/>
SELECT ?item ?startDate ?endDate ?archivedAtLabel ?inventoryNumber WHERE {
    ?item tdmlt:P1 tdml:Q1;
          tdmlt:P6 tdml:Q3; # à nancy
          tdmlt:P4 ?startDate;
          tdmlt:P5 ?endDate;
          tdmlp:P7 ?archivalStatement.
    ?archivalStatement tdmlps:P7 ?archivedAt;
                       tdmlpq:P8 ?inventoryNumber.
          
    SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
}

Chronologie des séances

#defaultView:Timeline
PREFIX tdml: <https://tredemulor.wikibase.cloud/entity/>
PREFIX tdmlt: <https://tredemulor.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?date ?commune ?communeLabel WHERE {
    ?item tdmlt:P1 tdml:Q7;
          tdmlt:P6 ?commune; # à nancy
          tdmlt:P11 ?date.
          
    SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
}

Délibérations où sont citées les personnes

PREFIX tdml: <https://tredemulor.wikibase.cloud/entity/>
PREFIX tdmlt: <https://tredemulor.wikibase.cloud/prop/direct/>
SELECT ?human ?humanLabel ?date ?deliberation ?deliberationLabel WHERE {

    ?deliberation tdmlt:P1 tdml:Q10;
                  tdmlt:P13 ?human;
                  tdmlt:P10 ?seance.
    
    ?seance tdmlt:P11 ?date.
  
    ?human tdmlt:P1 tdml:Q11.
          
    SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
}

Lieux

Nombre de délibérations pour chaque lieu et dates de première et dernière apparitions

PREFIX tdml: <https://tredemulor.wikibase.cloud/entity/>
PREFIX tdmlt: <https://tredemulor.wikibase.cloud/prop/direct/>
SELECT ?place ?placeLabel (COUNT(?deliberation) AS ?deliberations) (MIN(?date) AS ?firstDate) (MAX(?date) AS ?lastDate) WHERE {
    ?deliberation tdmlt:P1 tdml:Q10;
                  tdmlt:P14 ?place;
                  tdmlt:P10 ?seance.
    
    ?seance tdmlt:P11 ?date.

    SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
}
GROUP BY ?place ?placeLabel
ORDER BY DESC(?deliberations)

Délibérations où sont cités les lieux

PREFIX tdml: <https://tredemulor.wikibase.cloud/entity/>
PREFIX tdmlt: <https://tredemulor.wikibase.cloud/prop/direct/>
SELECT ?place ?placeLabel ?date ?deliberation ?deliberationLabel WHERE {
    ?deliberation tdmlt:P1 tdml:Q10;
                  tdmlt:P14 ?place;
                  tdmlt:P10 ?seance.
    
    ?seance tdmlt:P11 ?date.

    SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
}